* Test of MPC948 driving 25 Ohm line with 10 Ohm Series termination
*        clamp voltages                    
* maximum mpc948 output current, minimum Zo
B_973_max nd_ps_max nd_gc_max lvcmos_max_out lvcmos_in  LOW
+ file = 'MPC948.ibs'
+ model = 'COU21'
+ typ=max  power=on

R_series_min lvcmos_max_out  t_line_max_in  Series_R

Tr_min 0 t_line_max_in 0 Tline_max_out Z0=tline_min_Z td=tlinedel
C1_min  0 Tline_max_out loadC_min

B_973_nom nd_ps_nom nd_gc_nom lvcmos_nom_out lvcmos_in   LOW
+ file = 'MPC948.ibs'
+ model = 'COU21'
+ typ=typ  power=on
*
R_series_nom lvcmos_nom_out  t_line_nom_in  Series_R

Tr_nom 0 t_line_nom_in 0 Tline_nom_out Z0=tline_nom_Z td=tlinedel
C1_nom  0 Tline_nom_out loadC_nom


B_973_min nd_ps_min nd_gc_min lvcmos_min_out lvcmos_in  LOW
+ file = 'MPC948.ibs'
+ model = 'COU21'
+ typ=min  power=on
*
R_series_max lvcmos_min_out  t_line_min_in  Series_R

Tr_max 0 t_line_min_in 0 Tline_min_out Z0=tline_max_Z td=tlinedel
C1_max  0 Tline_min_out loadC_max

VHigh HIGH 0 3.3V
VLOW  LOW  0 0V
.param tline_nom_Z=25
.param tline_min_Z=22.5
.param tline_max_Z=27.5
.param loadC_nom=5pf
.param loadC_min=5pf
.param loadC_max=5pf
.param Series_R=10
.param tlinedel=3ns
*
*                         V1  V2    TD   TR   TF   PW   PER
VIN  lvcmos_in 0  PULSE ( 0   3.3   1n   1N   1N   32N  64N)
*    r1   21 0  40
.tran .01n 50n
.option post
.graph tran v(Tline_min_out) v(Tline_max_out) v(Tline_nom_out)

.alter change series R to 20 Ohms
.param Series_R=20
.alter change series R to 30 Ohms
.param Series_R=30
.end