* Simulate solution to Dally & Poulton Problem 5-12, period = 6ns
*
* DC source  value of source does not really matter for this sim
.param Vdd=3.3V
V0 a0 0 vdd
L0 a0 a 1uH

*Rank 1
* zero volt voltage source to allow plotting current
Vmeas_1 a r0in dc 0
R0 r0in b 0.00067
C0 b 0 60nF

*Rank 2
Vmeas_2 a l1in dc 0
L1 l1in c 83.333pH
R1 c d 0.0083
C1 d 0 120nF

*Rank 3
Vmeas_3 a l2in dc 0
L2 l2in e 166pH
R2 e f 0.0165
C2 f 0 600uF

* Current Load
*              v1 v2 delay rise fall width period
I1 aaa 0 pulse 0  10 20n   1n   1n   0     6n
Vmeaus_load a aaa dc 0V

* Vref is an ac voltage source, GIO is a voltage to current amp with
* gain of 1 controlled by Vref.  There may be a simpler way to get
* AC current source but this should work.  There are two current sources
* I1 and GIO in parallel, should work fine, currents add

Vref vacref 0 ac 1
GIO  gio_out 0 vacref 0 1
Vmeas_ac gio_out a dc 0

* Transient simulation (this will use I1)
* transient and AC simulations will be computed independetly, with
* source for other one at zero
.tran 1ps 100ns
* AC simulation (this will use ac source, Vref driving GIO)
*           start-f end-f
.ac dec 100  1000     1e9

.options post
.end